< návrat zpět

MS Excel

Téma: Postupné vyhledávání v matici rss

Zaslal/a Agamic 12.1.2018 15:30

Zdravim,
potřeboval bych poradit se vzorcem do Excelu a podmínka je, že musí být v jednom řádku.
Zkoušel sem zkombinovat dvě funkce POZVYHLEDAT vnořené do INDEXu, ale EXCEL mi to bohužel nechce vzít.
DO HODNOTY XX bych potřeboval vložit výsledek z prvního POZVYHLEDAT.

Děkuji

Můj vzorec:


INDEX([MATICE.xlsm]Sheet1!$1:$1000;
POZVYHLEDAT(BD13;[MATICE.xlsm]Sheet1!$B:$B;0);
POZVYHLEDAT(BD11;[MATICE.xlsm]Sheet1!$XX:$XX;0))

Pokus o vnoření EXCEL:

INDEX([MATICE.xlsm]Sheet1!$1:$1000;
POZVYHLEDAT(BD13;[MATICE.xlsm]Sheet1!$B:$B;0);
POZVYHLEDAT(BD11;[MATICE.xlsm]Sheet1!
$(POZVYHLEDAT(BD13;[MATICE.xlsm]Sheet1!$B:$B;0)):
$(POZVYHLEDAT(BD13;[MATICE.xlsm]Sheet1!$B:$B;0));0))

Zaslat odpověď >
xlnc(12.1.2018 17:54)#039022
avatar
Jaký "jeden řádek"???
Co to je "XX"?
Průsečík řádků 1:1000 a sloupce B? Takhle definujete tabulku?
A ta spodní část s tou horní souvisí jak?

Děs běs.citovat
Pavlus(12.1.2018 18:36)#039023
avatar
Řekl bych, že kolega pouze potřebuje vytvořit odkaz na oblast z "proměnných".
K tomuto ti pomohou excelové funkce ODKAZ a NEPŘÍMÝ.ODKAZ.
P.citovat
elninoslov(12.1.2018 18:55)#039024
elninoslov
??? Neviem či rozumiem správne dotazu. Za prvé to nebude fungovať na zatvorený súbor MATICA.xlsm, ale iba keď je otvorený spolu so súborom, v ktorom chcete zobrazovať výsledok. Za druhé neprehľadávajte celé stĺpce a celé riadky. Snáď má tá podivnosť nejaké medze, nie ?
Ak som mimo, tak nič. Ale prílohu (prílohy ak sa jedná o viac súborov) priložte tak či tak.
Příloha: zip39024_matice-hledej.zip (14kB, staženo 24x)
citovat
Agamic(15.1.2018 9:44)#039056
avatar
Omlouvám se za špatně formulovaný dotaz a za děs běs.
Do souboru vklad_hodnot.xlsx bych potřeboval vložit váhu, ze souboru MATICE.xlsm.
Ocením každou radu co nedělat a proč, v Excelu sem samouk a to kolikrát není nejlepší.
Příloha: zip39056_soubor_matice.zip (13kB, staženo 25x)
citovat
xlnc(15.1.2018 10:27)#039057
avatar
Supervzorec použitý při obou OTEVŘENÝCH souborech v sešitu Vklad_hodnot:

=INDEX(POSUN([MATICE.xlsx]List1!$1:$1;POZVYHLEDAT(B3;[MATICE.xlsx]List1!$B:$B;0)-1;0);1;POZVYHLEDAT(B4;POSUN([MATICE.xlsx]List1!$1:$1;POZVYHLEDAT(B3;[MATICE.xlsx]List1!$B:$B;0)-1;0);0)+1)

Jestliže zdrojový soubor zavřete, máte smůlu. Proto jsem řešení vložil na druhý list v přiloženém souboru, kde je i zdrojová matice.
Příloha: zip39057_matice_reseni.zip (8kB, staženo 29x)
citovat
Agamic(15.1.2018 13:58)#039062
avatar
Děkuju mockrát,
přesně co potřebuji. 1citovat
Agamic(15.1.2018 14:33)#039063
avatar
Ještě drobný dotaz, šlo by nahradit funkci POSUN, aby šlo načítat hodnoty i ze zavřeného sešitu nebo na to už je třeba VBA?
Děkujicitovat
elninoslov(15.1.2018 20:10)#039069
elninoslov
OFFSET/POSUN nepôjde do zatvoreného súboru. Ak by išlo o číselné hodnoty, a bol by to rozumne veľký dopredne určený rozsah, tak som to očúral takto:
=INDEX('Z:\MATICA\[MATICE.xlsx]List1'!$D$3:$AM$1000;MATCH($C$2;'Z:\MATICA\[MATICE.xlsx]List1'!$B$3:$B$1000;0);MATCH($C$3;INDEX(1*'Z:\MATICA\[MATICE.xlsx]List1'!$D$3:$AM$1000;MATCH($C$2;'Z:\MATICA\[MATICE.xlsx]List1'!$B$3:$B$1000;0));0)+1)

=INDEX('Z:\MATICA\[MATICE.xlsx]List1'!$D$3:$AM$1000;POZVYHLEDAT ($C$2;'Z:\MATICA\[MATICE.xlsx]List1'!$B$3:$B$1000;0);POZVYHLEDAT ($C$3;INDEX(1*'Z:\MATICA\[MATICE.xlsx]List1'!$D$3:$AM$1000;POZVYHLEDAT ($C$2;'Z:\MATICA\[MATICE.xlsx]List1'!$B$3:$B$1000;0));0)+1)

no a ak by to bol všetko text
=INDEX('Z:\MATICA\[MATICETEXT.xlsx]List1'!$D$3:$AM$1000;MATCH($D$2;REPT('Z:\MATICA\[MATICETEXT.xlsx]List1'!$B$3:$B$1000;1);0);MATCH($D$3;INDEX(REPT('Z:\MATICA\[MATICETEXT.xlsx]List1'!$D$3:$AM$1000;1);MATCH($D$2;REPT('Z:\MATICA\[MATICETEXT.xlsx]List1'!$B$3:$B$1000;1);0));0)+1)

=INDEX('Z:\MATICA\[MATICETEXT.xlsx]List1'!$D$3:$AM$1000;POZVYHLEDAT ($D$2;OPAKOVAT('Z:\MATICA\[MATICETEXT.xlsx]List1'!$B$3:$B$1000;1);0);POZVYHLEDAT ($D$3;INDEX(REPT('Z:\MATICA\[MATICETEXT.xlsx]List1'!$D$3:$AM$1000;1);POZVYHLEDAT ($D$2;OPAKOVAT('Z:\MATICA\[MATICETEXT.xlsx]List1'!$B$3:$B$1000;1);0));0)+1)
Příloha: zip39069_matica.zip (28kB, staženo 26x)
citovat

Uživatelské menu

Nejste přihlášen(a)
avatar\n

Menu

Formulář Faktura

Formulář Faktura IV

Oblíbený formulář Faktura byl vylepšen a rozšířen.
Více se dočtete zde.

Helios iNuvio

Používáte podnikový systém Helios iNuvio? Potřebujete pomoci se správou nebo vyvinout SQL proceduru? Více informací naleznete na stránce Helios iNuvio.

On-line nástroje