< návrat zpět

MS Excel

Téma: Maticový vzorec. rss

Zaslal/a czhoumer 1.4.2020 10:47

Dobrý den.
Zkouším maticový vzorec na zjištění dnešního dne ve zvířecím zvěrokruhu. A nějak se mi nedaří viz. příloha.
Děkuji za pomoc.

Příloha: xlsx46319_pokus.xlsx (47kB, staženo 27x)
Zaslat odpověď >
Strana:  1 2   další »
elninoslov(1.4.2020 11:03)#046320
elninoslov
=IFERROR(INDEX($F$3:$F$7;MATCH(1;($D$1>=$B$3:$B$7)*($D$1<=$D$3:$D$7);0));"Chyba")
=IFERROR(INDEX($F$3:$F$7;POZVYHLEDAT(1;($D$1>=$B$3:$B$7)*($D$1<=$D$3:$D$7);0));"Chyba")
alebo nematicový
=IFERROR(INDEX($F$3:$F$7;SUMPRODUCT(($D$1>=$B$3:$B$7)*($D$1<=$D$3:$D$7)*(ROW($F$3:$F$7)-2)));"Chyba")
=IFERROR(INDEX($F$3:$F$7;SOUČIN.SKALÁRNÍ(($D$1>=$B$3:$B$7)*($D$1<=$D$3:$D$7)*(ŘÁDEK($F$3:$F$7)-2)));"Chyba")
či
=IFERROR(INDEX($F$3:$F$7;SUMPRODUCT(($D$1>=$B$3:$B$7)*($D$1<=$D$3:$D$7)*{1;2;3;4;5}));"Chyba")
=IFERROR(INDEX($F$3:$F$7;SOUČIN.SKALÁRNÍ(($D$1>=$B$3:$B$7)*($D$1<=$D$3:$D$7)*{1;2;3;4;5}));"Chyba")citovat
czhoumer(1.4.2020 12:01)#046323
avatar
Děkuji moc za radu !!!

Musel jsem místo IFERROR napsat CHYBHODN. (Excel 2010)citovat
elninoslov(1.4.2020 12:41)#046324
elninoslov
Našiel som ešte jeden zaujímavý vzorček bez tabuľky, len je potrebné si skontrolovať tie dátumy v poli:
=LOOKUP(--TEXT(D1;"mdd");{101\121\220\321\421\521\621\724\824\924\1024\1123\1222;"Kozoroh"\"Vodnář"\"Ryby"\"Beran"\"Býk"\"Blíženci"\"Rak"\"Lev"\"Panna"\"Váhy"\"Štír"\"Střelec"\"Kozoroh"})
=VYHLEDAT(--HODNOTA.NA.TEXT(D1;"mdd");{101\121\220\321\421\521\621\724\824\924\1024\1123\1222;"Kozoroh"\"Vodnář"\"Ryby"\"Beran"\"Býk"\"Blíženci"\"Rak"\"Lev"\"Panna"\"Váhy"\"Štír"\"Střelec"\"Kozoroh"})citovat
marjankaj(1.4.2020 13:03)#046325
avatar
Ak je tabuľka správna, tak stačí jednoducho
=VLOOKUP($D$1;$B$3:$F$7;5)
len treba aktualizovať rok. Netuším ako sa v budúcnosti môže posunúť dátum. Aj prvý jarný deň sa posúva, síce nepatrne a pomaly ale predsa.citovat
czhoumer(1.4.2020 13:19)#046326
avatar
Děkuji všem !!!

Dělám si rodiný kalendář a chci vědět, kdo je "Beran" "Vepř" "Voda" a kdy má narozky.

Jsem hlava děravá a palice medvědí !!! 5citovat
marjankaj(1.4.2020 19:55)#046327
avatar
Tu je ako sa menia dátumy v jednotlivých rokoch.

https://www.astrohoroskop.sk/znamenie-zverokruhu?y=2019

https://sk.wikipedia.org/wiki/Zvieratn%C3%ADk
Příloha: xlsx46327_horoskop.xlsx (11kB, staženo 18x)
citovat
czhoumer(2.4.2020 8:03)#046328
avatar
Ještě mám problém.

Jak vyhledat jméno "Zdenka" a datum svátku.
Příloha: xlsx46328_pokus.xlsx (18kB, staženo 24x)
citovat
elninoslov(2.4.2020 9:46)#046329
elninoslov
maticový?
=INDEX(C3:C368;MIN(IF(IFERROR(SEARCH(B1;B3:B368);0)>0;ROW(B3:B368)-2)))
=INDEX(C3:C368;MIN(KDYŽ(IFERROR(HLEDAT(B1;B3:B368);0)>0;ŘÁDEK(B3:B368)-2)))
alebo iba
=MIN(IF(IFERROR(SEARCH(B1;B3:B368);0)>0;C3:C368))
=MIN(KDYŽ(IFERROR(HLEDAT(B1;B3:B368);0)>0;C3:C368))citovat
czhoumer(2.4.2020 9:57)#046330
avatar
Moc děkuji.
Funguje to !!! 5citovat
elninoslov(2.4.2020 13:00)#046331
elninoslov
Nie nefunguje!
1. opravte si oddelenie mien:
Anetta. Aneta
Maxmilian, Maxmilián,Maximilian
Amálie. Libuše
Oliver Olivia, Olívie
Michaela ,Michala
2. Vzorec sa musí upraviť tak, aby hľadal presné meno, nie iba jeho časť. Teda pridať oddeľovač mien ", " na začiatok aj koniec:
=MIN(IF(IFERROR(SEARCH(", "&B1&", ";", "&B3:B368&", ");0)>0;C3:C368))
=MIN(KDYŽ(IFERROR(HLEDAT(", "&B1&", ";", "&B3:B368&", ");0)>0;C3:C368))
Inak Vám totiž na tieto nájde zlý dátum, lebo sú časťou iného mena:
Gabriel      Dita         Ema          Ota          Alex         Ivo          
Emil         Kamila       Jarmil       Antonin      Jan          Ivan         
Ladislav     Petr         Nora         Libor        Viktor       Lada         
Alena        Bohuslav     Marcel       Nina         Erik         Bohdan       
Evžen        Martin       Tibor        Ondřej       Iva          Julia        
Dana         Daniel       Dan          Miloslav     Šimon        Simon        
Simeon       Štěpán
3. Tieto mená sú tam 2x (v rôznych dátumoch):
Kamila
Petr
Miloslav
4. Ak by ste chcel eliminovať dátum 0 (0.1.1900), ktorý dostanete pri neexistujúcom mene, tak treba zmeniť vzorec na takýto:
=IFERROR(INDEX(C3:C368;MATCH(TRUE;SEARCH(", "&B1&", ";", "&B3:B368&", ")>0;0));"")
=IFERROR(INDEX(C3:C368;POZVYHLEDAT(PRAVDA;HLEDAT(", "&B1&", ";", "&B3:B368&", ")>0;0));"")
alebo tento nematicový:
=IFERROR(LOOKUP(TRUE;SEARCH(", "&B1&", ";", "&B3:B368&", ")>0;C3:C368);"")
=IFERROR(VYHLEDAT(PRAVDA;HLEDAT(", "&B1&", ";", "&B3:B368&", ")>0;C3:C368);"")
PS: V Office 2010 CZ je potrebné funkciu IFERROR premenovať na CHYBHODN. Vo vyšších verziách Office CZ sa už podľa všetkého dá použiť aj názov IFERROR. Ak máte ešte starší Office 2003, treba IFERROR funkciu nahradiť konštrukciou
IF(ISERROR(X);0;X)
KDYŽ(JE.CHYBHODN(X);0;X)citovat

Strana:  1 2   další »

Uživatelské menu

Nejste přihlášen(a)
avatar\n

Menu

Formulář Faktura

Formulář Faktura IV

Oblíbený formulář Faktura byl vylepšen a rozšířen.
Více se dočtete zde.

Helios iNuvio

Používáte podnikový systém Helios iNuvio? Potřebujete pomoci se správou nebo vyvinout SQL proceduru? Více informací naleznete na stránce Helios iNuvio.

On-line nástroje