MS Excel

Téma: Vyhledání nejbližšího nižšího data

Zaslal/a Rop 7.3.2023 15:20

Vážení,
potřebuji vyhledat nejbližší nižší datum, které je přiřazeno k určitému textu. SVYHLEDAT mi na toto samozřejmě nefunguje.
Sloupce A a B jsou vstupní data. Ve sloupci C chci výsledek. Sloupce E a F jsou "databáze" údajů, ze kterých má být hledáno.
Pro toto zatání se má vyhledat 1. 1. 2023.
Prosím existuje nějaká funkce, která by byla vhodná?
Díky.

Příloha: xlsx

54583_vyhledat_datum.xlsx (9kB, staženo 4x)

Zaslat odpověď >

Jiří497(7.3.2023 17:03)#054586

Umím to jen s pomocným sloupcem. V pomocném sloupci je rozdíl mezi zadaným datumem a prohledávánými datumy. Hledá se minimální kladné číslo.
Jedná se o maticový vzorec, který se ukončuje Ctrl+shift+Enter

=INDEX(F2:G6;POZVYHLEDAT(MIN(KDYŽ(G:G>=0;G:G));G2:G6;0);1) P.S. Nemá se vyhledat 1.1.2023, ale 1.2.2023

Příloha: xlsx

54586_54583_vyhledat_datum.xlsx (13kB, staženo 3x)

citovat

elninoslov(7.3.2023 17:25)#054587

Pre Excel 2019, 2021, 365:
=MAXIFS(F2:F6;F2:F6;"<"&A2;E2:E6;B2)
pre Excel 2010+
=AGGREGATE(14;4;(F2:F6<A2)*(E2:E6=B2)*F2:F6;1)
inak maticový vzorec
=LARGE(IF((F2:F6<A2)*(E2:E6=B2);F2:F6;FALSE);1)
=LARGE(KDYŽ((F2:F6<A2)*(E2:E6=B2);F2:F6;NEPRAVDA);1)citovat

Rop(7.3.2023 18:30)#054588

elninoslov napsal/a:

Pre Excel 2019, 2021, 365:
=MAXIFS(F2:F6;F2:F6;"<"&A2;E2:E6;B2)

Díky. Kdybych asi si budu muset někde sehnat jen seznam funkcí excelu.citovat

lubo(7.3.2023 23:19)#054589

Možností je docela dost:

=MAX((E2:E6=B2) * (F2:F6<=A2) * (F2:F6))
=MAX(FILTER(F2:F6;(E2:E6=B2)*(F2:F6<=A2)))
=VYHLEDAT(A2;SORT(FILTER(F2:F6;E2:E6=B2)))
=SVYHLEDAT(A2;SORT(FILTER(F2:F6;E2:E6=B2));1)citovat

Uživatelské menu

Nejste přihlášen(a)

Formulář Faktura

Formulář Faktura IV

Oblíbený formulář Faktura byl vylepšen a rozšířen.
Více se dočtete zde.

Helios iNuvio

Používáte podnikový systém Helios iNuvio? Potřebujete pomoci se správou nebo vyvinout SQL proceduru? Více informací naleznete na stránce Helios iNuvio.