MS Excel

Ahoj, prosím o radu jak sestavit vzorec pro vrácení hodnoty na základě dvou podmínek.

Příklad:

V tabulce Prodeje mám ve sloupci A kód zboží a ve sloupci B cenu zboží. V tabulce Ceník je zboží s cenovými hladinami kde ve sloupci A je vždy kód zboží a v dalších sloupcích B - H jsou ceny dle slevových hladin.

No a já bych potřeboval do sloupce C v listu Prodeje napsat vzorec tak, aby našel v listu Ceník např: kód 123456 (Prodeje A5 s cenou 42 (Prodeje B5), kterou najde v ceníku v D5 a vrátí hodnotu pojmenování sloupce z buňky D1 (Cena 3) atd. když vzorec rozkopíruju aby mně to za splnění podmínky shody kódu a ceny vždy vrátilo název cenové hladiny)

Děkuji

Jiří497(8.4.2021 12:26)#050347

Třeba takto:
=VYHLEDAT(B2;NEPŘÍMÝ.ODKAZ("Ceník!A"&POZVYHLEDAT(A2;Ceník!$A$2:$A$8;)+1&":H"&POZVYHLEDAT(A2;Ceník!$A$2:$A$8;)+1;PRAVDA);Ceník!$A$1:$H$1)

Příloha: xlsx

50347_50346_vzor.xlsx (11kB, staženo 15x)

citovat

elninoslov(8.4.2021 14:22)#050349

Prípadne o kúsok kratší:
=LOOKUP(B2;OFFSET(Ceník!$B$1:$H$1;MATCH(A2;Ceník!$A$2:$A$8;0););Ceník!$B$1:$H$1)
=VYHLEDAT(B2;POSUN(Ceník!$B$1:$H$1;POZVYHLEDAT(A2;Ceník!$A$2:$A$8;0););Ceník!$B$1:$H$1)citovat

Morfeuss(8.4.2021 17:11)#050351

Použil a upravil jsem tento vzorec do svých ostrých dat a funguje.

Původní:
=VYHLEDAT(B2;POSUN(Ceník!$B$1:$H$1;POZVYHLEDAT(A2;Ceník!$A$2:$A$8;0););Ceník!$B$1:$H$1)

Upravený:
=VYHLEDAT(J2;POSUN('[Zásoby 8.4.2021.xlsx]List1'!$K$1:$BO$1;POZVYHLEDAT(C2;'[Zásoby 8.4.2021.xlsx]List1'!$A:$A;0););'[Zásoby 8.4.2021.xlsx]List1'!$K$1:$BO$1)

Vypadá to, ale že hledá jen přibližnou nikoli přesnou shodu.

Co s tím?

Díkycitovat

elninoslov(8.4.2021 19:16)#050353

=INDEX(Ceník!$B$1:$H$1;;MATCH(B2;OFFSET(Ceník!$B$1:$H$1;MATCH(A2;Ceník!$A$2:$A$8;0););0))
=INDEX(Ceník!$B$1:$H$1;;POZVYHLEDAT(B2;POSUN(Ceník!$B$1:$H$1;POZVYHLEDAT(A2;Ceník!$A$2:$A$8;0););0))citovat

Morfeuss(8.4.2021 20:16)#050354

Děkuji za úpravu, předěláno do ostrých dat a funguje perfektně.citovat

Morfeuss(9.4.2021 14:49)#050361

Můžu poprosit ještě o vzorec, který mně vrátí hodnotu (cenu) na základě splnění dvou podmínek (IČ a kód)? Respektive to samé co nyní, ale teď to porovnávalo kód a cenu a vracelo pojmenování sloupce. Já teď potřebuji aby mně to vracelo cenu na základě shody IČ a kódu.

Příloha: xlsx

50361_vzor-2.xlsx (10kB, staženo 16x)

citovat

elninoslov(9.4.2021 15:04)#050362

Maticový vzorec (Ctrl+Shift+Enter):
=INDEX(Ceník!$C$2:$C$8;MATCH(1;(Ceník!$A$2:$A$8=A2)*(Ceník!$B$2:$B$8=B2);0))
=INDEX(Ceník!$C$2:$C$8;POZVYHLEDAT(1;(Ceník!$A$2:$A$8=A2)*(Ceník!$B$2:$B$8=B2);0))
alebo normálny, ale iba pre prípad, že sú zoskupené IČ aj Kódy:
=INDEX(Ceník!$C$2:$C$8;MATCH(B2;OFFSET(Ceník!$B$1;MATCH(A2;Ceník!$A$2:$A$8;0);;COUNTIF(Ceník!$A$2:$A$8;A2));0)+MATCH(A2;Ceník!$A$2:$A$8;0)-1)
=INDEX(Ceník!$C$2:$C$8;POZVYHLEDAT(B2;POSUN(Ceník!$B$1;POZVYHLEDAT(A2;Ceník!$A$2:$A$8;0);;COUNTIF(Ceník!$A$2:$A$8;A2));0)+POZVYHLEDAT(A2;Ceník!$A$2:$A$8;0)-1)
EDIT:
Ešte ma napadol jeden normálny nematicový, keď nemusia byť zoskupené, ale musí byť dodržané, že IČ a Kód nie sú nikdy rovnaké, a dvojica sa v cenníku vyskytuje iba 1x:
=INDEX(Ceník!$C$2:$C$8;MATCH(2;MMULT(COUNTIF($A2:$B2;Ceník!$A$2:$B$8);{1;1});0))
=INDEX(Ceník!$C$2:$C$8;POZVYHLEDAT(2;SOUČIN.MATIC(COUNTIF($A2:$B2;Ceník!$A$2:$B$8);{1;1});0))citovat

Téma: Vrácení hodnoty na základě 2 podmínek

Uživatelské menu

Menu

On-line nástroje

Formulář Faktura

Formulář Faktura IV

Aktivní diskuse

Makro smyčka

Makro smyčka

Čas od do

Čas od do

Čas od do

Čas od do

Čas od do

Jméno
Kontrola
Text