• Úvod
• Excel návod
• Excel šablony
• Nástěnka
• Mobility
• Tipy na výlet
• Galerie
• Fórum

Příspěvky uživatele

A prečo chcete nahrádzať natívnu funkcionalitu Excelu (Revízia - Zabezpečiť hárok) ?

Píšete o liste, ale v cykle zamykáte/odomykáte všetky listy zošitu. Tak ako to je ?

Tie čísla sú vždy vzostupné po 1?
a) Ak nie, potom treba na dohľadanie nasledujúceho použiť :
=INDEX(Čísla!$A$2:$A$400;MATCH(H10;Čísla!$A$2:$A$400;0)+1)
=INDEX(Čísla!$A$2:$A$400;POZVYHLEDAT(H10;Čísla!$A$2:$A$400;0)+1)
b) Ak áno, potom stačí asi iba
=H10+1
c) Dá sa urobiť makro, ktoré sa Vás opýta na počet štítkov, a nakopíruje ich aj s číslami za Vás. Musí sa zistiť, či netreba vkladať zlomy strán, aby boli štítky správne vytlačené a nerozkladali sa "cez" stránky.

d) Alebo makro, ktoré bude postupne tlačiť zadaný počet lístkov, ale vytvorená bude len 1 stránka, v ktorej bude makro meniť čísla a posielať stránky na tlačiareň.

Iba nápad. Ale nepočíta sa s tým, že bude chýbať počiatočný alebo koncový údaj, a tiež sa počíta s tým, že sú hodnoty vzostupné, tak ako je v príklade.
=IF(B2<>"";B2;C1+(AVERAGE(MAX($C$1:$C1);MIN($B3:$B$12))-MAX($C$1:$C1)))

=KDYŽ(B2<>"";B2;C1+(PRŮMĚR(MAX($C$1:$C1);MIN($B3:$B$12))-MAX($C$1:$C1)))

EDIT: Vymenil som prílohu o 8:51, lebo som si uvedomil, že je nesprávna. :)

Od Office 2010 (vrátane) vyššie. Ak sa nemýlim.
Application.CommandBars.ExecuteMso ("PrintPreviewAndPrint")
Problém je, že makro ďalej pokračuje. Nečaká na žiadne voľby, tlač, na nič, a nevie ani o prípadnom zrušení tlače. Spomínam to preto, že treba na to myslieť.
Keď som pred rokmi hľadal nejaké riešenie pozastavenia makra na dobu zobrazenia tohto dialógu, nič dostupné ešte nebolo.

Napadá ma toto:
=INDEX(Stĺpec výsledku;MATCH(1;(SUBTOTAL(103;OFFSET(Prvý stĺpec;ROW(Prvý stĺpec)-2;;1))=1)*(Prvý stĺpec=E1);0))

=INDEX(Stĺpec výsledku;POZVYHLEDAT(1;(SUBTOTAL(103;POSUN(Prvý stĺpec;ŘÁDEK(Prvý stĺpec)-2;;1))=1)*(Prvý stĺpec=E1);0))

E1 - hľadaná hodnota
ROW(Prvý stĺpec)-2 - treba prispôsobiť podľa umiestnenia tabuľky, aby prvé číslo dalo 0
SUBTOTAL - dá True ak je riadok viditeľný
MATCH - nájde pozíciu prvej zhody
INDEX(Stĺpec výsledku ... - stĺpec v tabuľke, z ktorého sa má brať výsledok

=IF(INT(C2-B2)=0;"";INT(C2-B2)&" "&IF(INT(C2-B2)=1;"deň ";IF(INT(C2-B2)<5;"dni ";"dní ")))&TEXT(C2-B2-INT(C2-B2);"h:mm")&" hodín"
=KDYŽ(CELÁ.ČÁST(C2-B2)=0;"";CELÁ.ČÁST(C2-B2)&" "&KDYŽ(CELÁ.ČÁST(C2-B2)=1;"deň ";KDYŽ(CELÁ.ČÁST(C2-B2)<5;"dni ";"dní ")))&HODNOTA.NA.TEXT(C2-B2-CELÁ.ČÁST(C2-B2);"h:mm")&" hodín"

Dátum
=DATEVALUE(LEFT(A2;FIND("?";SUBSTITUTE(A2;"/";"?";3))-1))
=DATUMHODN(ZLEVA(A2;NAJÍT("?";DOSADIT(A2;"/";"?";3))-1))

Čas
=IFERROR(TIMEVALUE(REPLACE(A2;1;FIND("?";SUBSTITUTE(A2;"/";"?";3));""));"")
=IFERROR(ČASHODN(NAHRADIT(A2;1;NAJÍT("?";DOSADIT(A2;"/";"?";3));""));"")

Na overenie existencie predsa stačí iba:
=ISNUMBER((FIND(","&B1&",";","&A1&",")))
=JE.ČISLO((NAJÍT(","&B1&",";","&A1&",")))

Pozícia:
=IFERROR(FIND(","&B1&",";","&A1&",");0)
=IFERROR(NAJÍT(","&B1&",";","&A1&",");0)

Index:
=IFERROR(LEN(LEFT(A1;FIND(","&B1&",";","&A1&",")-1))-LEN(SUBSTITUTE(LEFT(A1;FIND(","&B1&",";","&A1&",")-1);",";""))+1;0)
=IFERROR(DÉLKA(ZLEVA(A1;NAJÍT(","&B1&",";","&A1&",")-1))-DÉLKA(DOSADIT(ZLEVA(A1;NAJÍT(","&B1&",";","&A1&",")-1);",";""))+1;0)

Počet:
=IF(A1="";0;LEN(A1)-LEN(SUBSTITUTE(A1;",";""))+1)
=KDYŽ(A1="";0;DÉLKA(A1)-DÉLKA(DOSADIT(A1;",";""))+1)

Súčet:
=SUMPRODUCT(--("0"&TRIM(MID(SUBSTITUTE(A1;",";REPT(" ";LEN(A1)));1+(ROW(OFFSET($A$1;;;LEN(A1)))-1)*LEN(A1);LEN(A1)))))
=SOUČIN.SKALÁRNÍ(--("0"&PROČISTIT(ČÁST(DOSADIT(A1;",";OPAKOVAT(" ";DÉLKA(A1)));1+(ŘÁDEK(POSUN($A$1;;;DÉLKA(A1)))-1)*DÉLKA(A1);DÉLKA(A1)))))


Výskytov:
=(LEN(A1)-LEN(SUBSTITUTE(A1;B1;"")))/LEN(B1)
=(DÉLKA(A1)-DÉLKA(DOSADIT(A1;B1;"")))/DÉLKA(B1)

Pr.

Priložte aj ten textový súbor. Takéto textopiplačky som mal kedysi rád :)

A to mazacie makro zmente len na tento 1 riadok kódu:
Sub Vymazat() ' Vymazat Makro
Range("A4") = 1
End Sub

Takto ???

Ako vraví veny. Na toto je makro zbytočné. Text s upozornením cez vzorec, kontrola stavu cez vzorec, a farbenie cez PF.

Priložte prílohu. Cítim z popisu, že chcete vytvoriť kompletný sklad. To ľahké mať teda nebudete. Jednotky kg, ks, m3, lit, a podobne nevkladajte makrom. Pri každej skladovej položke majte záznam akú má jednotku, a môžete to dohľadať VLOOKUP-om rovnako ako ostatné info o tovare (cena, počet na sklade...)

Príklad. Príde Vám to divné ? Mne áno. Čo majú robiť tie makrá ? Ak to isté len s inými dátami, viazanými na zmenené bunky, tak treba použiť parametrizovanú procedúru a nie 30 skoro rovnakých makier. Ďalej treba špecifikovať, či tých 30 makier vplýva tiež na výpočty (nastane duplikovanie evidencie zmien - preto EnableEvents=False). Princíp je v tom, že sa musí pri každom prepočte listu zistiť voči skrytému listu so starými hodnotami, zoznam zmien. Tieto zmeny sa uložia do kolekcie, ktorá sa potom Kontrolou spracuje a volá makro podľa čísla.

PS OT: Tak nech sa všetci držíme v novom roku lepšie ako v starom :)

Uživatelské menu

Nejste přihlášen(a)

• přihlásit
• registrace

\n

Menu

On-line nástroje

Formulář Faktura

Aktivní diskuse