< návrat zpět

MS Excel


Téma: Počet aktivních dnů rss

Zaslal/a 10.10.2019 8:27

Dobrý den,
potřeboval bych poradit s následujícím případem, mám ve sloupci P vklady a ve sloupci O vždy datum vkladu a potřeboval bych zjistit počet "aktivních dnů", tedy dnů kdy byl vložen nějaký vklad.

Ale na druhou stranu dny, kdy bylo více vkladů, je třeba počítat jako 1 aktivní den. Je nato prosím nějaký fígl?

Děkuji.

Zaslat odpověď >

#044508
avatar
Vklad (P) a datum (O) jde ruku v ruce, nebo uvedení datumu neznamená nutně vklad?citovat
#044509
avatar
Kontingenčná tabuľka do hodnoty počet z dátum a do filtra vklad.citovat
#044527
avatar
nebo ??

=SUMA(KDYŽ(ČETNOSTI(O3:O100;O3:O100)>0,1;1))

maticovým vzorcem

taky funguje 9

ještě přidávám kontrolu sloupce P

=SUMA((P3:P100>0)*KDYŽ(ČETNOSTI(F3:F100;F3:F100)>0,1;1))

opět maticově !!!
snad OK 2citovat
#044537
avatar

Zbygi napsal/a:

nebo ??

=SUMA(KDYŽ(ČETNOSTI(O3:O100;O3:O100)>0,1;1))

maticovým vzorcem

taky funguje

ještě přidávám kontrolu sloupce P

=SUMA((P3:P100>0)*KDYŽ(ČETNOSTI(F3:F100;F3:F100)>0,1;1))

opět maticově !!!
snad OK


Asi jsem to zadání nenapsal moc jasně, takže jsem vytvořil soubor na ukázku. Sloupce jsem použil A a B pro zjednodušení a hodnot jen pár.

https://uloz.to/file/xvuwfMh5sWhI/funkce-pro-zjisteni-poctu-unikarnich-dni-wall-cz-xlsx

Děkuji za pomoc.citovat
#044538
avatar

Darbujan napsal/a:

Vklad (P) a datum (O) jde ruku v ruce, nebo uvedení datumu neznamená nutně vklad?


Když je tam datum, tak je tam vždy vklad. Problém je v tom že potřebuji zjistit počet unikátních datumů, bez ohledu na čas.

Více zde v přiloženém souboru https://uloz.to/file/xvuwfMh5sWhI/funkce-pro-zjisteni-poctu-unikarnich-dni-wall-cz-xlsxcitovat
#044539
elninoslov
Problém je aj v tom, že to je text (!), a nie dátumo-čas.
Teda nematicovo
=SUM(IF(FREQUENCY(INT(B2:B100);INT(B2:B100))>0,1;1))-1
=SUMA(KDYŽ(ČETNOSTI(CELÁ.ČÁST(B2:B100);CELÁ.ČÁST(B2:B100))>0,1;1))-1


ak tam je dátum, ale nie vklad, tak sa dátum nemá započítať, teda maticovo:
=SUM(IF(FREQUENCY(IF(A2:A100<>"";INT(B2:B100););INT(B2:B100))>0;1))-1
=SUMA(KDYŽ(ČETNOSTI(KDYŽ(A2:A100<>"";CELÁ.ČÁST(B2:B100););CELÁ.ČÁST(B2:B100))>0;1))-1


ak tam je vklad, ale nieje dátum, teda sa nemá aký započítať, FREQUENCY/ČETNOSTI to berie ako 0, a tú ignoruje, teda tento prípad rieši prvý vzorec.

EDIT: Predošlé vracajú o 1 viac, teda buď započítava aj tie prázdne alebo FALSE/NEPRAVDA v podmienke, alebo FREQUENCY vracia pole o 1 väčšie, riešením by bolo vždy odrátať 1 na konci.
Alebo oprava maticovo :
=SUM(--(FREQUENCY(IF((A2:A100<>"")*(B2:B100<>"");INT(B2:B100);"");INT(B2:B100))>0))
=SUMA(--(ČETNOSTI(KDYŽ((A2:A100<>"")*(B2:B100<>"");CELÁ.ČÁST(B2:B100);"");CELÁ.ČÁST(B2:B100))>0))
citovat
#044543
avatar

elninoslov napsal/a:

Problém je aj v tom, že to je text (!), a nie dátumo-čas.
Teda nematicovo
=SUM(IF(FREQUENCY(INT(B2:B100);INT(B2:B100))>0,1;1))-1
=SUMA(KDYŽ(ČETNOSTI(CELÁ.ČÁST(B2:B100);CELÁ.ČÁST(B2:B100))>0,1;1))-1

ak tam je dátum, ale nie vklad, tak sa dátum nemá započítať, teda maticovo:
=SUM(IF(FREQUENCY(IF(A2:A100<>"";INT(B2:B100););INT(B2:B100))>0;1))-1
=SUMA(KDYŽ(ČETNOSTI(KDYŽ(A2:A100<>"";CELÁ.ČÁST(B2:B100););CELÁ.ČÁST(B2:B100))>0;1))-1

ak tam je vklad, ale nieje dátum, teda sa nemá aký započítať, FREQUENCY/ČETNOSTI to berie ako 0, a tú ignoruje, teda tento prípad rieši prvý vzorec.

EDIT: Predošlé vracajú o 1 viac, teda buď započítava aj tie prázdne alebo FALSE/NEPRAVDA v podmienke, alebo FREQUENCY vracia pole o 1 väčšie, riešením by bolo vždy odrátať 1 na konci.
Alebo oprava maticovo :
=SUM(--(FREQUENCY(IF((A2:A100<>"")*(B2:B100<>"");INT(B2:B100);"");INT(B2:B100))>0))
=SUMA(--(ČETNOSTI(KDYŽ((A2:A100<>"")*(B2:B100<>"");CELÁ.ČÁST(B2:B100);"");CELÁ.ČÁST(B2:B100))>0))


Děkuji, perfektní.citovat

Uživatelské menu

Nejste přihlášen(a)
avatar\n

Menu

On-line nástroje

Formulář Faktura

Formulář Faktura III

Oblíbený formulář Faktura byl vylepšen a rozšířen. Formulář faktura III
Více se dočtete zde.

Aktivní diskuse