< návrat zpět

MS Excel


Téma: averageifs rss

Zaslal/a 6.11.2019 13:55

Zdravim,

mám vzorec viz níže a potřebuji do něj přidat ještě jednu podmínku a pro sloupec N6:N6000 ještě "C"

tzn aby výsledná hodnota byla na základě podmínky "Y" a "C" v buňkách N6:N6000

=AVERAGEIFS(M6:M6000;N6:N6000;"Y";B6:B6000;"*TZ*")

Díky za radu

Zaslat odpověď >

#044910
avatar
Ahoj
zkusil jsem to maticově, ale bez dat které si domýšlím nevím zda to bude OK

=(SUMA((N6:N25="C")+(N6:N25="Y")*(B6:B25="*TZ*")*(M6:M25)))/(SUMA((N6:N25="C")+(N6:N25="Y")*(B6:B25="*TZ*")*1))

ještě upraveno

jen si to prodlužte na vaší tabulkucitovat
#044912
elninoslov
=SUM((((N6:N20="y")+(N6:N20="c"))>0)*NOT(ISERROR(SEARCH("tz";B6:B20)))*(M6:M20))/SUM((((N6:N20="y")+(N6:N20="c"))>0)*NOT(ISERROR(SEARCH("tz";B6:B20))))

=SUMA((((N6:N20="y")+(N6:N20="c"))>0)*NE(JE.CHYBHODN(HLEDAT("tz";B6:B20)))*(M6:M20))/SUMA((((N6:N20="y")+(N6:N20="c"))>0)*NE(JE.CHYBHODN(HLEDAT("tz";B6:B20))))

ale musí to ísť aj jednoduchšie ...citovat
#044913
avatar
Díky moc rady, ale když použiji oba vzorce tak mi excel hází #HODNOTA.

Nevím proč.

Pro lepší představivost posílám v příloze vzorovou tabulku, ve které jsou uvedené data, jak vypadají u mě.

Můžete mě prosím poradit?

Děkuji
Příloha: xlsx44913_priklad_1.xlsx (10kB, staženo 6x)
citovat
#044914
avatar
*Můžete micitovat
icon #044915
avatar
Napríklad takto:

=SUMPRODUCT(M6:M6000*((N6:N6000="Y")+(N6:N6000="C"))*(LEFT(B6:B6000;2)="TZ"))/SUMPRODUCT(((N6:N6000="Y")+(N6:N6000="C"))*(LEFT(B6:B6000;2)="TZ"))

Ak to TZ môže byť i niekde uprostred reťazca, potom trebárs takto:

=SUMPRODUCT(M6:M6000*((N6:N6000="Y")+(N6:N6000="C"))*((LEN(B6:B6000)-LEN(SUBSTITUTE(B6:B6000; "TZ";"")))=2))/SUMPRODUCT(((N6:N6000="Y")+(N6:N6000="C"))*((LEN(B6:B6000)-LEN(SUBSTITUTE(B6:B6000; "TZ";"")))=2))

Iná možnosť napr, maticovo:
=IFERROR(AVERAGE(IF(ISNUMBER(MATCH(N6:N6000;{"Y";"C"};0));IF(LEFT(B6:B2000;2)="TZ";M6:M6000)));"")

Niekedy je ale kvôli prehľadnosti výpočtu predsa len vhodné použiť pomocný stĺpec a v ňom otestovať podmienku (napr. na prítomnosť Y alebo C v stĺpci status z hore uvedeného zadania).citovat
#044916
avatar
v buŇce D1 je moje řešení (ještě upravené) a funguje

myslím že jsi nezadal vzorce maticově
Příloha: xlsx44916_44913_priklad_1.xlsx (11kB, staženo 3x)
citovat
icon #044917
avatar
@elninoslov
miesto (((N6:N20="y")+(N6:N20="c"))>0) stačí v tvojom vzorci zadať ((N6:N20="y")+(N6:N20="c")), ak to chceš jednoduchšie :)citovat
#044923
avatar
díky moc za radycitovat
icon #044937
eLCHa
=SUMA(SUMIFS(M3:M5997;N3:N5997;{"C";"Y"};B3:B5997;"*TZ*"))/SUMA(COUNTIFS(N3:N5997;{"C";"Y"};B3:B5997;"*TZ*"))https://exceljet.net/formula/sumifs-with-multiple-criteria-and-or-logiccitovat

Uživatelské menu

Nejste přihlášen(a)
avatar\n

Menu

On-line nástroje

Formulář Faktura

Formulář Faktura III

Oblíbený formulář Faktura byl vylepšen a rozšířen. Formulář faktura III
Více se dočtete zde.

Aktivní diskuse

Rozdělení tabulky u více listů

Klamerka • 21.11. 16:01

Excel vzorec

marjankaj • 21.11. 14:40

Excel vzorec

elninoslov • 21.11. 14:36

Excel vzorec

Kuldaml • 21.11. 14:29

Excel vzorec

marjankaj • 21.11. 14:26

Vyhledání nejvyšší hodnoty na základě podmínek

elninoslov • 21.11. 13:36

Vyhledání nejvyšší hodnoty na základě podmínek

Josselinne • 21.11. 13:34