< návrat zpět

MS Excel


Téma: Vyhledání nejvyšší hodnoty na základě podmínek rss

Zaslal/a 21.11.2019 10:11

Dobrý den,prosím o radu Potřebovala bych dostat určité data tedy nejvyšší hodnotu = poslední datum nakládky z listu "zdroj dat" do druhého listu "2019" do sloupce "last loading date"na základě vyhledávání čísla kontraktu.

Použila jsem tento vzorec viz níže, ale vzorec funguje 50/50, ne vždy mi vyhledá správné poslední datum nakládky
:(

=MAX(NEPŘÍMÝ.ODKAZ(CONCATENATE("'zdroj dat'!$AB";POZVYHLEDAT($A35;'zdroj dat'!$A33:$A10029;0)+3;":$AB";POZVYHLEDAT($A35;'zdroj dat'!$A33:$A10029;0)+3+COUNTIF('zdroj dat'!$A33:$A10029;$A35)-1)))

Zaslat odpověď >

#045026
avatar
A uhádnete vy, jakou mám dnes barvu ponožek?citovat
#045030
avatar
prosím poraďte, kde se vkládá příloha.

Děkujicitovat
#045031
elninoslov
Ten vzorec ste si asi nekrokovala, čo ?
"+3" - znamená to, že sú bunky zlúčené po 3 riadkoch, alebo že oblasti posunuté o 3? Ak posunuté (čo sú), tak nie o 3, ale oni predsa začínajú na 33 riadku, takže +32. Ak to znamená že sú zlúčené tak nielen +3, ale aj +COUNTIF()*3.

To "COUNTIF" znamená, že idú kontrakty vždy po sebe a niesú pomiešané ?

Zadávate to ako maticový vzorec ?

Príloha by bola lepšia, nech si to nemusíme domýšľať a vytvárať...

=MAX(INDIRECT("'zdroj dat (2)'!$AB"&MATCH($A35;'zdroj dat (2)'!$A33:$A10029;0)+32&":$AB"&MATCH($A35;'zdroj dat (2)'!$A33:$A10029;0)+32+COUNTIF('zdroj dat (2)'!$A33:$A10029;$A35)-1))
=MAX(NEPŘÍMÝ.ODKAZ("'zdroj dat (2)'!$AB"&POZVYHLEDAT($A35;'zdroj dat (2)'!$A33:$A10029;0)+32&":$AB"&POZVYHLEDAT($A35;'zdroj dat (2)'!$A33:$A10029;0)+32+COUNTIF('zdroj dat (2)'!$A33:$A10029;$A35)-1))
citovat
#045032
avatar
Soubor je příliš velký, mohu poslat na email?citovat
#045033
avatar
Ano, zavadám jako maticový vzorec. Pro upřesnění Vám mohu soubor poslat emailem.citovat
#045034
elninoslov
Kľudne pošlite, mail je v mojom konte, a hore som Vám dal vyskúšanú a funkčnú verziu na variant keď idú po sebe. Ja by som sa ale asi zbavil toho INDIRECT/NEPŘÍMÝ.ODKAZ a dal tam asi OFFSET/POSUN.

=MAX(OFFSET('zdroj dat (2)'!$AB32;MATCH($A35;'zdroj dat (2)'!$A33:$A10029;0);;COUNTIF('zdroj dat (2)'!$A33:$A10029;$A35)-1))
=MAX(POSUN('zdroj dat (2)'!$AB32;POZVYHLEDAT($A35;'zdroj dat (2)'!$A33:$A10029;0);;COUNTIF('zdroj dat (2)'!$A33:$A10029;$A35)-1))


Ak sú pomiešané (nejdú po sebe), ale aj keď idú po sebe, dá sa použiť (maticovo):
=MAX(IF('zdroj dat (2)'!$A33:$A10029=$A35;'zdroj dat (2)'!$AB33:$AB10029))
=MAX(KDYŽ('zdroj dat (2)'!$A33:$A10029=$A35;'zdroj dat (2)'!$AB33:$AB10029))

alebo ak máte najnovší Office tak ten má novú funkciu MAXIFS (nematicovo)
=MAXIFS('zdroj dat (2)'!$AB33:$AB10029;'zdroj dat (2)'!$A33:$A10029;$A35)

Príklady v prílohe.
Příloha: xlsx45034_priklad-maxif.xlsx (15kB, staženo 3x)
citovat
#045048
elninoslov
Takže aj podľa mailu, to bude chyba v adresácii.
=IFERROR(MAX(OFFSET('zdroj dat'!$AB$3;MATCH($A3;'zdroj dat'!$A$4:$A$10000;0);;COUNTIF('zdroj dat'!$A$4:$A$10000;$A3)));"")
=IFERROR(MAX(POSUN('zdroj dat'!$AB$3;POZVYHLEDAT($A3;'zdroj dat'!$A$4:$A$10000;0);;COUNTIF('zdroj dat'!$A$4:$A$10000;$A3)));"")
citovat

Uživatelské menu

Nejste přihlášen(a)
avatar\n

Menu

On-line nástroje

Formulář Faktura

Formulář Faktura III

Oblíbený formulář Faktura byl vylepšen a rozšířen. Formulář faktura III
Více se dočtete zde.

Aktivní diskuse

Maticový vzorec?

veny • 6.12. 12:30

Maticový vzorec?

AL • 6.12. 11:32

Maticový vzorec?

veny • 6.12. 10:04

Vekové rozdelenie po 5 rokoch VYRIEŠENÉ

kabaka • 6.12. 7:27

Vekové rozdelenie po 5 rokoch VYRIEŠENÉ

elninoslov • 6.12. 6:51

jak spočítat znaky

elninoslov • 6.12. 6:33

Vekové rozdelenie po 5 rokoch VYRIEŠENÉ

kabaka • 5.12. 18:58