• Úvod
• Excel návod
• Excel šablony
• Nástěnka
• Mobility
• Tipy na výlet
• Galerie
• Fórum

MS Excel

Téma: PowerQuery - priradenie hodnôt

Zaslal/a Daniel_11 2.11.2020 10:17

Zdravím, mám 2 tabuľky. Jedna sú mená v riadkoch a chcem k nim priradiť pohlavie a druhá sú 2 stĺpce pre mená mužov a žien. Je možné priradiť v PQ k menám pohlavie tak, že ak nájde zhodu buď v stĺpci "muž" alebo "žena", tak mi napíše názov toho stĺpca?

Druhá otázka, je možné proporčne rozpočítanie hodnôt za základe iných hodnôt v PQ? Vo vzore mám vzorec, ktorý to robí, no je to možné v PQ? Ďakujem pekne.

Příloha: 48737_powequery.xlsx (13kB, staženo 19x)

Zaslat odpověď >

---

lubo(2.11.2020 11:22)#048738

Jde to:
První otázka:

// načtení tabulky pohlavie do tabulky pohlavie
// pohlavie
let
Zdroj = Excel.CurrentWorkbook(){[Name="Tabulka3"]}[Content]
in
Zdroj

// Načtení tabulky dáta
// dáta
let
Zdroj = Excel.CurrentWorkbook(){[Name="Tabulka1"]}[Content],

// konverze tabulky pohlavie do tvaru vhodného pro připojení
// není to nezbytné, vše lze dělat mnoha způsoby
MenoPohlavie = Table.UnpivotOtherColumns(pohlavie, {}, "Pohlavie", "Meno"),

// spojení tabulek
#"Sloučené dotazy" = Table.NestedJoin(Zdroj, {"Meno"}, MenoPohlavie, {"Meno"}, "MenoPohlavie", JoinKind.LeftOuter),
#"Rozbalené Pohlavie" = Table.ExpandTableColumn(#"Sloučené dotazy", "MenoPohlavie", {"Pohlavie"}, {"Pohlavie"})
in
#"Rozbalené Pohlavie"


Druhá otázka:
// načtení Suma2 do tab "Suma2"
// Suma2
let
Zdroj = Excel.CurrentWorkbook(){[Name="Tabulka8"]}[Content],
#"Změněný typ" = Table.TransformColumnTypes(Zdroj,{{"Typ", type text}, {"Suma2", Int64.Type}})
in
#"Změněný typ"

// Data2
let
// Načtení data2
Zdroj = Excel.CurrentWorkbook(){[Name="Tabulka6"]}[Content],
#"Změněný typ" = Table.TransformColumnTypes(Zdroj,{{"Typ", type text}, {"Deň", type text}, {"Suma", Int64.Type}, {"Suma2", type number}}),
// celková suma v data2 podle dne:
SumaDen = Table.Group(#"Změněný typ", {"Deň"}, {{"SumaDen", each List.Sum([Suma]), type number}}),
// Připojení koeficintů k řádkům
#"Sloučené dotazy" = Table.NestedJoin(#"Změněný typ", {"Deň"}, Suma2, {"Typ"}, "TabSuma2", JoinKind.LeftOuter),
#"Rozbalené TabSuma2" = Table.ExpandTableColumn(#"Sloučené dotazy", "TabSuma2", {"Suma2"}, {"TabSuma2"}),
#"Sloučené dotazy1" = Table.NestedJoin(#"Rozbalené TabSuma2", {"Deň"}, SumaDen, {"Deň"}, "SumaDen", JoinKind.LeftOuter),
#"Rozbalené SumaDen" = Table.ExpandTableColumn(#"Sloučené dotazy1", "SumaDen", {"SumaDen"}, {"SumaDen"}),
// Do dalšího sloupce přidáme výpočet podle vzorce
#"Přidané: Vlastní" = Table.AddColumn(#"Rozbalené SumaDen", "Suma2_pq", each [Suma]*[TabSuma2]/[SumaDen])
in
#"Přidané: Vlastní"citovat

Uživatelské menu

Nejste přihlášen(a)

• přihlásit
• registrace

\n

Menu

On-line nástroje

Formulář Faktura

Aktivní diskuse