MS Excel

ahojte,

obracím se na vás s prosbou, hlava mi teď moc nejde. Potřebuju vytvořit vzorec pro Timeline (pro sloupce START a END). Fungovat by to měla tak, že když napíšu někde v kalendáři jedničku, tak sloupce START najde první jedničku zleva a vrátí datum z druhého řádku. Do sloupce END najde první jedničku zprava a k datumu z druhého řádku přičte 6 dní. Dá se to prosím nějak vyřešit bez maker a VBA? Tento soubor bude na online 365 office a tam nic takového nefunguje.

Díky za případné rady a podněty

Dalibor

Zaslat odpověď >

elninoslov(1.9.2019 11:20)citovat#044104

Pre prehľadnosť si nadefinujte 2 Definované názvy:
ROZSAH_DATUM
=OFFSET(List1!$G$2;;;;COUNT(List1!$3:$3))
=POSUN(List1!$G$2;;;;POČET(List1!$3:$3))
a ROZSAH_DAT
=OFFSET(ROZSAH_DATUM;ROW()-2;)
=POSUN(ROZSAH_DATUM;ŘÁDEK()-2;)

Štart nájdite napr (obyčajný vzorec : Enter):
=INDEX(ROZSAH_DATUM;;MATCH(1;ROZSAH_DAT;0))
=INDEX(ROZSAH_DATUM;;POZVYHLEDAT(1;ROZSAH_DAT;0))
End nájdite (maticový vzorec : Ctrl+Shift+Enter):
=INDEX(ROZSAH_DATUM;;MAX(IF(ROZSAH_DAT=1;COLUMN(ROZSAH_DATUM);0))-6)+6
=INDEX(ROZSAH_DATUM;;MAX(KDYŽ(ROZSAH_DAT=1;SLOUPEC(ROZSAH_DATUM);0))-6)+6

Ak sú jedničky vždy za sebou, a tvoria iba jednu oblasť, tak potom (normálny vzorec : Enter)
=D5+COUNTIF(ROZSAH_DAT;1)*7-1

Lugr(1.9.2019 11:57)citovat#044105

Dobrý den,

elninoslov je možné, že u END je něco špatně?

elninoslov(1.9.2019 13:38)citovat#044106

Mám nové auto. A div sa svete, nieje na ňom všetko lepšie ako na starom (rovnaký model). Teda odpoveď znie : Samozrejme! Vždy môže byť niečo "špatně". Ale pokiaľ nepoviete, čo je zle, ja to hľadať nebudem. Tu máte oba varianty. červený je matica, zelený je normál vzorec. Zodpovedajú Vami požadovaným výsledkom. Tak priložte príklad, nech sa to upraví.

Příloha: xlsx

44106_44103_timeline-test.xlsx (18kB, staženo 21x)

Lugr(1.9.2019 13:53)citovat#044107

Omlouvám se, mě to ve sloupci END pořád psalo #HODNOTA a nemohl jsem přijít na to proč.

Děkuji za odpověď.

Jinak Vám přeji, ať nové auto dlouho a dobře slouží.

elninoslov(1.9.2019 14:24)citovat#044108

Tú chybu Vám dá, ak použijete maticový vzorec obyčajným stlačením Enter. Maticový vzorec sa zadáva Ctrl+Shift+Enter. Je určený na to, aby našiel poslednú jedničku v prípade, že nejdú po sebe, ale že sú medzi nimi medzery.
Naopak ten druhý vzorec, je obyčajný (nematicový), a počíta s tým, že jedničky idú po sebe, v jednej jedinej skupine v riadku.
Máte si len vybrať, lebo nevieme, ako presne zapisujete dáta.

jaks.dalibor(1.9.2019 15:08)citovat#044109

ahojte,

sice zatím nevím, jak to funguje, ale důležité je, že to funguje. Až mi to hlava trochu pobere, tak se na to detailněji podívám, abych to uměl taky stvořit.

Díky moc všem, opět jste nezklamali. Klidný zbytek neděle

D.

Lugr(1.9.2019 15:53)citovat#044110

Tak to byla moje chyba. Děkuji za vysvětlení.

elninoslov(1.9.2019 17:19)citovat#044112

A ešte je možnosť použiť aj na nájdenie poslednej jedničky nematicový vzorec:
=INDEX(ROZSAH_DATUM;;LOOKUP(2;1/(ROZSAH_DAT=1);COLUMN(ROZSAH_DATUM)-6))+6
=INDEX(ROZSAH_DATUM;;VYHLEDAT(2;1/(ROZSAH_DAT=1);SLOUPEC(ROZSAH_DATUM)-6))+6

Téma: Interaktivní timeline

Uživatelské menu

Menu

Formulář Faktura

Formulář Faktura IV

Helios iNuvio

On-line nástroje