< návrat zpět

MS Excel


Téma: kalendar spocitanie od datumu rss

Zaslal/a 25.11.2021 11:11

Zdravim a prosim o pomoc s vytvorenim makra. Mam kalendar a v nom zaznacene udaje chcel by som tam pridat fmakro aby my to spocitalo hodnoty ktore v nom mam zaznacene od urciteho datumu az po koniec roka. Predstavoval by som si to tak ze vyberiem datum kliknem na tlacidlo a zrata sa to vo vzorci. Musi tam byt nato vzorec lebo to budem pouzivat aj na mobile a tam makra nefunguju. Takze vyber rozsahu moze byt v makre ale finalne zratanie musi byt vo vzorci.
Nieco som uz skusal no nefunguje to uplne dobre. Viem ze robim chybu s tym xldown a pod funkciamy ale nedokazem vymysliet system aby to oznacilo tie bunky ktore ma.

Příloha: rar51588_kal.rar (30kB, staženo 5x)
Zaslat odpověď >

#051590
elninoslov
Takže ide o to, spočítať, koľko je tam buniek obsahujúcich písmeno "m"?citovat
#051594
avatar
Ano, tak aby sa to dalo nastavit od konkretneho datumu.citovat
#051596
elninoslov
Napadá ma zložitejší maticový vzorec (Ctrl+Shift+Enter), ale neviem či mobilný Excel žerie matice. Počiatočný dátum je v I1, a žiadne makro netreba:
=SUM(ISEVEN(ROW(C4:I108))*{1\1\1\1\1\1\1}*(C4:I108>=I1)*(C4:I108<DATE(YEAR(I1)+1;1;1))*ISODD(ROW(C5:I109))*{1\1\1\1\1\1\1}*(IFERROR(SEARCH("m";C5:I109);0)>0))
=SUMA(ISEVEN(ŘÁDEK(C4:I108))*{1\1\1\1\1\1\1}*(C4:I108>=I1)*(C4:I108<DATUM(ROK(I1)+1;1;1))*ISODD(ŘÁDEK(C5:I109))*{1\1\1\1\1\1\1}*(IFERROR(HLEDAT("m";C5:I109);0)>0))


EDIT:
Ale veď ono by stačilo asi iba COUNTIFS, normálne nematicovo:
=COUNTIFS(C4:I108;">="&I1;C4:I108;"<"&DATE(YEAR(I1)+1;1;1);C5:I109;"*m*")
=COUNTIFS(C4:I108;">="&I1;C4:I108;"<"&DATUM(ROK(I1)+1;1;1);C5:I109;"*m*")
citovat
#051597
avatar
Ten s countifs funguje na výbornú dakujem. Ani by ma nenapadlo že to pôjde aj bez makra zdalo sa mi to príliš zložité a nakoniec to išlo vyriešit pomerne jednoduchým vzorcom. Ešte raz dakujem.citovat
#051598
elninoslov
Tak len doplním ten najkomplikovanejší variant, ak sú mesiace na preskáčku vyplnené a nevyplnené, a potrebujete súčet X vyplnených od konca.

2 Definované názvy
MESIACE:
=OFFSET(Hárok1!$B$9;;;;LOOKUP(2;1/(Hárok1!$9:$9<>"");COLUMN(Hárok1!$9:$9))-1)
=POSUN(Hárok1!$B$9;;;;VYHLEDAT(2;1/(Hárok1!$9:$9<>"");SLOUPEC(Hárok1!$9:$9))-1)


SPLNENE:
=MATCH(Hárok1!$G$5;COUNTIF(OFFSET(Hárok1!$B$9;;COLUMNS(MESIACE)-COLUMN(MESIACE);;COLUMN(MESIACE)-1);"<>");0)
=POZVYHLEDAT(Hárok1!$G$5;COUNTIF(POSUN(Hárok1!$B$9;;SLOUPCE(MESIACE)-SLOUPEC(MESIACE);;SLOUPEC(MESIACE)-1);"<>");0)


no a výsledný vzorec:
=IFERROR(SUM(OFFSET(B9;;COLUMNS(MESIACE)-SPLNENE;;SPLNENE));SUM(MESIACE))
=IFERROR(SUMA(POSUN(B9;;SLOUPCE(MESIACE)-SPLNENE;;SPLNENE));SUMA(MESIACE))
citovat

Uživatelské menu

Nejste přihlášen(a)
avatar\n

Menu

On-line nástroje

Formulář Faktura

Formulář Faktura IV

Oblíbený formulář Faktura byl vylepšen a rozšířen.
Více se dočtete zde.

Aktivní diskuse

Vodorovný teploměr v buňce

GeorgeK • 1.12. 12:26

Vodorovný teploměr v buňce

elninoslov • 1.12. 10:21

Vodorovný teploměr v buňce

Stalker • 1.12. 10:01

Vodorovný teploměr v buňce

GeorgeK • 1.12. 9:15

Spustit makro v určitý čas

Baja • 28.11. 20:11

Spustit makro v určitý čas

elninoslov • 28.11. 17:09

Spustit makro v určitý čas

Baja • 28.11. 12:51