MS Excel

Dobrý den,
mám tento zápis:
=INDEX(DataPhm[@[PHM v M]];POZVYHLEDAT([@ID];DataPhm[@ID];0))
Na listu s tabulkou DataPhm mám sloupec ID, kde ID je jednoznačný identifikátor - spojení RZ a roku a měsíce.
A pak na listu s tabulkou DataWebdisp má výše uvedený vzorec. Zde mám také ID, které se shoduje s ID na druhém listu.
Jenže mně se doplní pouze první hodnota z listu s tabulkou DataPhm.
Přikládám soubor.
Můžete mi, prosím, poradit, jak upravit ten vzorec tak, aby se doplnily všechny hodnoty?
Děkuji.
Radek

Zaslat odpověď >

elninoslov(15.6.2022 11:22)#052892

Máte tam navyše @
=INDEX(DataPhm[@[PHM v M]];MATCH([@ID];DataPhm[@ID];0))
=INDEX(DataPhm[@[PHM v M]];POZVYHLEDAT([@ID];DataPhm[@ID];0))
vs
=INDEX(DataPhm[PHM v M];MATCH([@ID];DataPhm[ID];0))
=INDEX(DataPhm[PHM v M];POZVYHLEDAT([@ID];DataPhm[ID];0))citovat

Alfan(15.6.2022 12:50)#052896

Mockrát děkuji za pomoc.
Mohl byste mi, prosím, ještě poradit s maximem a minimem?
Soubor přikládám.

Na listu "dataphm" bych potřeboval do sloupce "BD" doplnit minimum a do sloupce "BE" maximum podle těchto kritérií.

Jednoznačný identifikátor je ve sloupci "Z" a je to SPZ auta.
A do sloupce "BD" tedy minimum by se doplnila nejnižší hodnota ze sloupce "AW" pro příslušnou SPZ a analogicky do sloupce "BE" zase maximum ze sloupce "AX" pro příslušnou SPZ.
Děkuji.
Radek

Příloha: zip

52896_min-a-max.zip (38kB, staženo 6x)

citovat

elninoslov(15.6.2022 14:04)#052898

Ak máte minimálne Office 2019 použite MINIFS/MAXIFS:
=MINIFS([Tach Start];[Kalkulační jednice];[@[Kalkulační jednice]])
=MAXIFS([Tach End];[Kalkulační jednice];[@[Kalkulační jednice]])
CZ ekvivalent nepoznám, možno nie je preložená...

ak máte staršiu verziu, tieto funkcie nemáte, použite maticový vzorec (zadávate pomocou Ctrl+Shift+Enter):
=MIN(IF([Kalkulační jednice]=[@[Kalkulační jednice]];[Tach Start]))
=MIN(KDYŽ([Kalkulační jednice]=[@[Kalkulační jednice]];[Tach Start]))
=MAX(IF([Kalkulační jednice]=[@[Kalkulační jednice]];[Tach End]))
=MAX(KDYŽ([Kalkulační jednice]=[@[Kalkulační jednice]];[Tach End]))

Příloha: zip